kazehakase/trunk/configure.ac

dnl Process this file with autoconf to produce a configure script.
AC_PREREQ(2.57)

AC_INIT(kazehakase, 0.1.7)
AM_INIT_AUTOMAKE(1.6)
AM_CONFIG_HEADER(config.h)

AC_ENABLE_SHARED(yes)
AC_ENABLE_STATIC(no)
AM_PROG_LIBTOOL
 
MOZILLA_REQUIRED=1.4
GTK_REQUIRED=2.0.0

AC_SUBST(MOZILLA_REQUIRED)
AC_SUBST(GTK_REQUIRED)


dnl **************************************************************
dnl Check for GtkMozEmbed.
dnl **************************************************************
PKG_CHECK_MODULES(MOZILLA_COMPONENT, mozilla-gtkmozembed)
dnl AC_DEFINE(ENABLE_MOZILLA_EMBED)
AC_SUBST(MOZILLA_COMPONENT_CFLAGS)
AC_SUBST(MOZILLA_COMPONENT_LIBS)

MOZILLA_INCLUDE_ROOT="`$PKG_CONFIG --variable=includedir mozilla-gtkmozembed`"
AC_SUBST(MOZILLA_INCLUDE_ROOT)

MOZILLA_HOME="`$PKG_CONFIG --variable=libdir mozilla-gtkmozembed`"
AC_SUBST(MOZILLA_HOME)

MOZILLA_VERSION="`$PKG_CONFIG --modversion mozilla-gtkmozembed`"
AC_SUBST(MOZILLA_VERSION)
dnl if test "x$MOZILLA_VERSION" == "x1.5a" -o "x$MOZILLA_VERSION" == "x1.5b" -o "x$MOZILLA_VERSION" == "x1.6a"; then
dnl   AC_DEFINE(MOZILLA_SNAPSHOT)
dnl fi

dnl allow user to override the autodetected mozilla version
dnl     - without arguments for cvs head

dnl **************************************************************
dnl Check Mozilla version.
dnl This code picked from Epiphany-1.0.1.
dnl **************************************************************

AC_MSG_RESULT($MOZILLA_VERSION$autodetect)

case "$MOZILLA_VERSION" in
  1.4) MOZILLA_SNAPSHOT=8 ;;
1.4.1) MOZILLA_SNAPSHOT=9 ;;
1.4.2) MOZILLA_SNAPSHOT=9 ;;
 1.5a) MOZILLA_SNAPSHOT=10 ;;
 1.5b) MOZILLA_SNAPSHOT=11 ;;
  1.5) MOZILLA_SNAPSHOT=11 ;; 
1.5.1) MOZILLA_SNAPSHOT=11 ;; 
 1.6a) MOZILLA_SNAPSHOT=12 ;;
 1.6b) MOZILLA_SNAPSHOT=12 ;;
  1.6) MOZILLA_SNAPSHOT=12 ;;
 1.7a) MOZILLA_SNAPSHOT=13 ;;
 1.7b) MOZILLA_SNAPSHOT=14 ;;
 1.7rc1) MOZILLA_SNAPSHOT=14 ;;
 1.7rc2) MOZILLA_SNAPSHOT=15 ;;
 1.7rc3) MOZILLA_SNAPSHOT=15 ;;
  1.7) MOZILLA_SNAPSHOT=15 ;;
  1.7.1) MOZILLA_SNAPSHOT=15 ;;
 1.8a) MOZILLA_SNAPSHOT=16 ;;
trunk) MOZILLA_SNAPSHOT=16 ;;
    *) AC_ERROR([
*****************************************************************************
Kazehakase can be built using Mozilla 1.4, 1.5a, 1.5b, 1.5, 1.5.1 or 
trunk snapshot, but the version available is $MOZILLA_VERSION.  

When using Mozilla trunk snapshot, a successful build is not guaranteed due 
to the frequently changing state of the Mozilla interfaces and the limited
resources of the Epiphany team to support non-release Mozilla snapshots.
*****************************************************************************])
esac

AC_DEFINE_UNQUOTED(MOZILLA_SNAPSHOT, $MOZILLA_SNAPSHOT, [Define mozilla snapshot])

dnl disable RTTI by default
AC_ARG_ENABLE(cpp-rtti,
        [  --enable-cpp-rtti       Enable C++ RTTI (for cvs gcc)],,
        enable_cpp_rtti=no)

if test "x$enable_cpp_rtti" = "xno"; then
  CXXFLAGS="-fno-rtti $CXXFLAGS"
fi


dnl **************************************************************
dnl Check for Gtk+2.
dnl **************************************************************
dnl Test for GTK+, and define GTK_CFLAGS and GTK_LIBS, if gthread is specified in MODULES, 
dnl pass to pkg-config
AM_PATH_GTK_2_0(2.0.0)
AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)

dnl **************************************************************
dnl Check for gettext.
dnl **************************************************************
ALL_LINGUAS="ja"
GETTEXT_PACKAGE=kazehakase
AC_SUBST(GETTEXT_PACKAGE)
AM_GLIB_GNU_GETTEXT
localedir="${datadir}/locale"
AC_SUBST(localedir)

dnl
dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
dnl
kz_save_LIBS=$LIBS
LIBS="$LIBS $GTK_LIBS"
AC_CHECK_FUNCS(bind_textdomain_codeset)
LIBS=$kz_save_LIBS


dnl **************************************************************
dnl Checks for programs.
dnl **************************************************************
AC_PROG_CXX
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_AWK


if test "x$GCC" = "xyes"; then
  case " $CFLAGS " in
  *[\ \ ]-Wall[\ \      ]*) ;;
  *) CFLAGS="$CFLAGS -Wall" ;;
  esac

  if test "x$enable_ansi" = "xyes"; then
    case " $CFLAGS " in
    *[\ \       ]-ansi[\ \      ]*) ;;
    *) CFLAGS="$CFLAGS -ansi" ;;
    esac

    case " $CFLAGS " in
    *[\ \       ]-pedantic[\ \  ]*) ;;
    *) CFLAGS="$CFLAGS -pedantic" ;;
    esac
  fi
fi

dnl **************************************************************
dnl Checks for libraries.
dnl **************************************************************
# FIXME: Replace `main' with a function in `-le':
AC_CHECK_LIB([e], [main])
# FIXME: Replace `main' with a function in `-links':
AC_CHECK_LIB([inks], [main])


dnl **************************************************************
dnl Checks for header files.
dnl **************************************************************
AC_HEADER_STDC
AC_CHECK_HEADERS([fcntl.h libintl.h stdlib.h string.h unistd.h])


dnl **************************************************************
dnl Checks for typedefs, structures, and compiler characteristics.
dnl **************************************************************
AC_C_CONST


dnl **************************************************************
dnl Checks for library functions.
dnl **************************************************************
AC_CHECK_FUNCS([setlocale strchr strtol uname memmove strerror])

dnl **************************************************************
dnl If have GTK+-2.2.x, using GTK+-2.4.0 backports. it should be after AM_PATH_GTK_2_0
dnl **************************************************************
if test x"$gtk_config_minor_version" = x"2" ; then
  AC_DEFINE_UNQUOTED(USE_GTK_2_2, 1, [Define using GTK+-2.4.0 backports])
fi

dnl **************************************************************
dnl Migemo 
dnl **************************************************************
AC_ARG_ENABLE(migemo, [  --enable-migemo
                          Enable Migemo (Japanese incremental search)])
if test x"$enable_migemo" = "xyes"; then
   AC_DEFINE(USE_MIGEMO, 1, [Define using Migemo support])
fi

AC_CONFIG_FILES([
Makefile
po/Makefile.in
src/Makefile
src/kazehakase
src/utils/Makefile
src/net/Makefile
src/mozilla/Makefile
src/actions/Makefile
src/bookmarks/Makefile
src/prefs_ui/Makefile
src/sidebar/Makefile
src/widget/Makefile
src/gtk24backports/Makefile
src/regex/Makefile
src/regex/pcre/Makefile
etc/Makefile
data/Makefile
data/icons/Makefile
kazehakase.spec
])

AC_OUTPUT