kazehakase/trunk/configure.ac

dnl Process this file with autoconf to produce a configure script.
AC_PREREQ(2.57)

AC_INIT(kazehakase, 0.4.3)
AM_INIT_AUTOMAKE(1.6)
AM_CONFIG_HEADER(config.h)

AC_ENABLE_SHARED(yes)
AC_ENABLE_STATIC(no)
AM_PROG_LIBTOOL
 
LT_VERSION_INFO="1:0:1"
LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
AC_SUBST(LT_VERSION_INFO)
AC_SUBST(LIBTOOL_EXPORT_OPTIONS)

AC_PATH_PROG([PKG_CONFIG], [pkg-config], [no])

AC_PROG_CXX
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_AWK

dnl disable RTTI by default
AC_ARG_ENABLE(cpp-rtti,
        [  --enable-cpp-rtti       Enable C++ RTTI (for cvs gcc)],,
        enable_cpp_rtti=no)

if test "x$enable_cpp_rtti" = "xno"; then
  AM_CXXFLAGS="-fno-rtti $AM_CXXFLAGS"
fi

dnl **************************************************************
dnl Check for GtkMozEmbed.
dnl **************************************************************
GECKO=
AC_ARG_WITH([gecko_engine],
        AS_HELP_STRING([--with-gecko-engine@<:@=mozilla|firefox|thunderbird|seamonkey|xulrunner@:>@],
                       [Whether to use mozilla, firefox or thunderbird or seamonkey xpcom (default: mozilla)]),
        [GECKO="$withval"])

dnl try to autodetect: if mozilla exists, use it, else try firefox, then thunderbird
if test "x$GECKO" = "x"; then
  if $PKG_CONFIG --exists firefox-xpcom; then
    GECKO=firefox
  elif $PKG_CONFIG --exists mozilla-firefox-xpcom; then
    GECKO=mozilla-firefox
  elif $PKG_CONFIG --exists mozilla-xpcom; then
    GECKO=mozilla
  elif $PKG_CONFIG --exists seamonkey-xpcom; then
    GECKO=seamonkey
  elif $PKG_CONFIG --exists thunderbird-xpcom; then
    GECKO=thunderbird
  elif $PKG_CONFIG --exists xulrunner-xpcom; then
    GECKO=xulrunner
  else
    AC_MSG_ERROR([no mozilla installation found])
  fi
elif test "x$with_gecko_engine" != "xmozilla" -a "x$with_gecko_engine" != "xfirefox" -a "x$with_gecko_engine" != "xthunderbird" -a "x$with_gecko_engine" != "xseamonkey" -a "x$with_gecko_engine" != "xmozilla-firefox" -a "x$with_gecko_engine" != "xxulrunner"; then
  AC_MSG_ERROR([unknown gecko engine name ($GECKO)])
fi
AC_SUBST(GECKO)

AC_MSG_RESULT([$GECKO])

case "$GECKO" in
mozilla) min_version=1.7 flavour=mozilla ;;
seamonkey) min_version=1.0 flavour=mozilla ;;
firefox) min_version=1.0 flavour=toolkit ;;
mozilla-firefox) min_version=1.0 flavour=toolkit ;;
thunderbird) min_version=0.8 flavour=toolkit ;;
xulrunner) min_version=1.8 flavour=toolkit ;;
esac

GECKO_FLAVOUR=$flavour
AC_SUBST(GECKO_FLAVOUR)

dnl **************************************************************
dnl Check for including gtkmozembed.
dnl **************************************************************
AC_ARG_ENABLE(gtkmozembed, [  --enable-gtkmozembed
                          Enable including GtkMozEmbed module],,
                enable_gtkmozembed=yes)
if test x"$enable_gtkmozembed" = "xyes"; then
  AC_DEFINE(ENABLE_GTKMOZEMBED, 1, [Define including GtkMozEmbed])
  GECKO_MODULE=$GECKO-xpcom
else
  GECKO_MODULE=$GECKO-gtkmozembed
fi
AM_CONDITIONAL(ENABLE_GTKMOZEMBED, test x"$enable_gtkmozembed" = "xyes")

PKG_CHECK_MODULES(MOZILLA_COMPONENT, $GECKO_MODULE >= $min_version)

AC_SUBST(MOZILLA_COMPONENT_CFLAGS)
AC_SUBST(MOZILLA_COMPONENT_LIBS)

MOZILLA_COMPONENT_VERSION="`$PKG_CONFIG --modversion $GECKO_MODULE`"
AC_SUBST(MOZILLA_COMPONENT_VERSION)

MOZILLA_INCLUDE_ROOT="`$PKG_CONFIG --variable=includedir $GECKO-xpcom`"
AC_SUBST(MOZILLA_INCLUDE_ROOT)

MOZILLA_HOME="`$PKG_CONFIG --variable=libdir $GECKO-xpcom`"
AC_SUBST(MOZILLA_HOME)

MOZILLA_PREFIX="`$PKG_CONFIG --variable=prefix $GECKO-xpcom`"
AC_SUBST(MOZILLA_PREFIX)


dnl *************************************************************************
dnl This is from Mozilla's configure.in. They set almost all the config stuff
dnl they need in mozilla-config.h Except for this compiler flag, which can't
dnl go in mozilla-config.h So we check the flag too and now we can include
dnl mozilla-config.h without breaking epiphany.
dnl This is really gcc-only
dnl Do this test using CXX only since some versions of gcc
dnl 2.95-2.97 have a signed wchar_t in c++ only and some versions
dnl only have short-wchar support for c++.
AC_LANG_PUSH(C++)
_SAVE_CPPFLAGS=$CPPFLAGS
_SAVE_CXXFLAGS=$CXXFLAGS
_SAVE_AM_CXXFLAGS=$AM_CXXFLAGS
AM_CXXFLAGS="$AM_CXXFLAGS -fshort-wchar"
CXXFLAGS="$CXXFLAGS $AM_CXXFLAGS"

AC_CACHE_CHECK(for compiler -fshort-wchar option,
    ac_cv_have_usable_wchar_option,
    [AC_TRY_RUN([#include <stddef.h>
                 int main () {
                   return (sizeof(wchar_t) != 2) ||
                          (wchar_t)-1 < (wchar_t) 0 ; } ],
                ac_cv_have_usable_wchar_option="yes",
                ac_cv_have_usable_wchar_option="no",
                ac_cv_have_usable_wchar_option="maybe")])

if test "$ac_cv_have_usable_wchar_option" != "yes"; then
    AM_CXXFLAGS=$_SAVE_AM_CXXFLAGS
fi


CFLAGS=""
CPPFLAGS="-I$MOZILLA_INCLUDE_ROOT -I$MOZILLA_INCLUDE_ROOT/widget -I$MOZILLA_INCLUDE_ROOT/layout -I$MOZILLA_INCLUDE_ROOT/helperAppDlg -I$MOZILLA_INCLUDE_ROOT/dom -I$MOZILLA_INCLUDE_ROOT/exthandler -I$MOZILLA_INCLUDE_ROOT/pipnss -I$MOZILLA_INCLUDE_ROOT/necko -I$MOZILLA_INCLUDE_ROOT/gfx -I$MOZILLA_INCLUDE_ROOT/content -I$MOZILLA_INCLUDE_ROOT/locale -I$MOZILLA_INCLUDE_ROOT/docshell `$PKG_CONFIG --cflags-only-I $GECKO-xpcom` -Wconversion -Wsign-compare -Werror"
CXXFLAGS="$AM_CXXFLAGS `$PKG_CONFIG --cflags-only-other $GECKO-xpcom`"

AC_MSG_RESULT([$CXXFLAGS])
dnl **************************************************************
dnl Check Mozilla API .
dnl This code picked from Epiphany-1.7.0.
dnl **************************************************************

dnl Changed from PRUnichar* to nsAString& in 1.8a1 and on aviary branch

dnl Determine gecko version
dnl We don't use the version from the .pc file, since that's the app version
dnl and not the Gecko version

AC_MSG_CHECKING([[for gecko version]])

gecko_version=`cat $MOZILLA_INCLUDE_ROOT/mozilla-config.h | grep MOZILLA_VERSION_U | awk '{ print $[3]; }' | tr ".ab+" " "`
if test -z "$gecko_version"; then
        gecko_version="1 7"
fi

gecko_version_major=`echo $gecko_version | awk '{ print $[1]; }'`
gecko_version_minor=`echo $gecko_version | awk '{ print $[2]; }'`

AC_MSG_RESULT([$gecko_version_major.$gecko_version_minor])

if test "$gecko_version_major" != "1" -o "$gecko_version_minor" -lt "7" -o "$gecko_version_minor" -gt "9"; then
        AC_MSG_ERROR([Unsupported Gecko version $gecko_version_major.$gecko_version_minor])
fi

if test "$gecko_version_major" = "1" -a "$gecko_version_minor" -ge "8"; then
        AC_DEFINE([HAVE_GECKO_1_8],[1],[Define if we have gecko 1.8])
fi
if test "$gecko_version_major" = "1" -a "$gecko_version_minor" -ge "9"; then
        AC_DEFINE([HAVE_GECKO_1_9],[1],[Define if we have gecko 1.9])
fi

AM_CONDITIONAL([HAVE_GECKO_1_8],[test "$gecko_version_major" = "1" -a "$gecko_version_minor" -ge "8"])
AM_CONDITIONAL([HAVE_GECKO_1_9],[test "$gecko_version_major" = "1" -a "$gecko_version_minor" -ge "9"])

AC_MSG_CHECKING([whether nsPIDOMWindow methods return nsPIDOMWindow*])

AC_COMPILE_IFELSE(
        [AC_LANG_PROGRAM(
                [[#include <nsPIDOMWindow.h>]],
                [[nsPIDOMWindow *w;
                  w->GetPrivateRoot ();]]
        )],
        [AC_DEFINE([MOZ_NSPIDOMWINDOW_RETURNNSPIDOMWINDOW_],[1],[Define if nsPIDOMWindow returns nsPIDOMWindow*]) result=yes],
        [result=no])

AC_MSG_RESULT([$result])

AC_MSG_CHECKING([whether nsIFilePicker methods expect nsAString&])

AC_COMPILE_IFELSE(
        [AC_LANG_PROGRAM(
                [[#include <nsEmbedString.h>
                  #include <widget/nsIFilePicker.h>]],
                [[nsIFilePicker *p;
                  p->SetDefaultString (nsEmbedString());]]
        )],
        [AC_DEFINE([MOZ_NSIFILEPICKER_NSASTRING_],[1],[Define if nsIFilePicker uses nsAString&]) result=yes],
        [result=no])

AC_MSG_RESULT([$result])

dnl Changed from char* to nsAString& in 1.8a1

AC_MSG_CHECKING([whether nsIMIMEInfo methods expect nsAString&])

AC_COMPILE_IFELSE(
        [AC_LANG_PROGRAM(
                [[#include <nsEmbedString.h>
                  #include <mimetype/nsIMIMEInfo.h>]],
                [[nsIMIMEInfo *p;
                  p->SetDescription (nsEmbedString());]]
        )],
        [AC_DEFINE([MOZ_NSIMIMEINFO_NSACSTRING_],[1],[Define if nsIMIMEInfo uses nsAString&]) result=yes],
        [result=no])

AC_MSG_RESULT([$result])

AC_MSG_CHECKING([whether nsICacheSession methods expect nsAString&])

AC_COMPILE_IFELSE(
        [AC_LANG_PROGRAM(
                [[#include <nsEmbedString.h>
                  #include <nkcache/nsICacheSession.h>]],
                [[nsICacheSession *p;
                  p->OpenCacheEntry (nsEmbedCString(),0, PR_FALSE, nsnull);]]
        )],
        [AC_DEFINE([MOZ_NSICACHESESSION_NSACSTRING_],[1],[Define if nsICacheSession uses nsAString&]) result=yes],
        [result=no])

AC_MSG_RESULT([$result])

AC_MSG_CHECKING([whether nsIHelperAppLauncherDialog methods expect PRBool])

AC_COMPILE_IFELSE(
        [AC_LANG_PROGRAM(
                [[#include <nsIHelperAppLauncherDialog.h>]],
                [[nsIHelperAppLauncherDialog *p;
                  p->Show (nsnull, nsnull, -1);]]
        )],
        [AC_DEFINE([MOZ_NSIHELPERAPPLAUNCHERDIALOG_NSPRBOOL_],[1],[Define if nsIHelperAppLauncharDialog uses PRBool]) result=yes],
        [result=no])

AC_MSG_RESULT([$result])

AC_MSG_CHECKING([whether NS_InitXPCOM3 exists])

AC_COMPILE_IFELSE(
        [AC_LANG_PROGRAM(
                [[#include <nsXPCOM.h>]],
                [[NS_InitXPCOM3(nsnull, nsnull, nsnull, nsnull, 0);]]
        )],
        [AC_DEFINE([MOZ_HAVE_NSINITXPCOM3_],[1],[Define if Gecko has NS_InitXPCOM3]) result=yes],
        [result=no])

AC_MSG_RESULT([$result])

AC_COMPILE_IFELSE(
        [AC_LANG_PROGRAM(
                [[#define MOZILLA_INTERNAL_API
                  #include <nsICanvasRenderingContextInternal.h>
                  #include <nsEmbedString.h>
                  #undef MOZILLA_INTERNAL_API]],
                [[nsICanvasRenderingContextInternal *p;
                  p->GetInputStream (nsEmbedCString(), nsEmbedString(), nsnull);]]
        )],
        [AC_DEFINE([MOZ_NSICANVASRENDERINGCONTEXTINTERNAL_HAVE_GETINPUTSTREAM_],[1],[Define if nsICanvasRenderingContextInternal has GetInputStream]) result=yes],
        [result=no])

AM_CONDITIONAL([MOZ_NO_NSICANVASRENDERINGCONTEXTINTERNAL_HAVE_GETINPUTSTREAM_], [test "$result" = "no"])
AC_MSG_RESULT([$result])

AC_CHECK_FILE([$MOZILLA_INCLUDE_ROOT/content/nsICanvasRenderingContextInternal.h],
        [AC_DEFINE([HAVE_NSICANVASRENDERINGCONTEXTINTERNAL_H],[1],[Define if nsICanvasRenderingContextInternal.h exists])])

AC_CHECK_FILE([$MOZILLA_INCLUDE_ROOT/nsIWebProgressListener2.h],
        [AC_DEFINE([HAVE_NSIWEBPROGRESSLISTENER2_H],[1],[Define if nsIWebProgressListener2.h exists])],
        [AC_CHECK_FILE([$MOZILLA_INCLUDE_ROOT/uriloader/nsIWebProgressListener2.h],
                [AC_DEFINE([HAVE_NSIWEBPROGRESSLISTENER2_H],[1],[Define if nsIWebProgressListener2.h exists])])])

AC_CHECK_FILE([$MOZILLA_INCLUDE_ROOT/nsITransfer.h],
        [AC_DEFINE([HAVE_NSITRANSFER_H],[1],[Define if nsITransfer.h exists])],
        [AC_CHECK_FILE([$MOZILLA_INCLUDE_ROOT/uriloader/nsITransfer.h],
                [AC_DEFINE([HAVE_NSITRANSFER_H],[1],[Define if nsITransfer.h exists])])])

AC_CHECK_FILE([$MOZILLA_INCLUDE_ROOT/nsIPresContext.h],
        [AC_DEFINE([HAVE_NSIPRESCONTEXT_H],[1],[Define if nsIPresContext.h exists])],
        [AC_CHECK_FILE([$MOZILLA_INCLUDE_ROOT/layout/nsIPresContext.h],
                [AC_DEFINE([HAVE_NSIPRESCONTEXT_H],[1],[Define if nsIPresContext.h exists])])])

dnl Not a simple file check due to the header being in the SDK since 1.8a6
dnl https://bugzilla.mozilla.org/show_bug.cgi?id=271068

AC_CHECK_FILES([$MOZILLA_INCLUDE_ROOT/nsIPassword.h
                $MOZILLA_INCLUDE_ROOT/wallet/nsIPassword.h
                $MOZILLA_INCLUDE_ROOT/passwordmgr/nsIPassword.h],
        [AC_DEFINE([HAVE_NSIPASSWORD_H],[1],
        [Define if mozilla nsIPassword header is available])])

dnl Check for nsIDocShell::GetSecurityUI
dnl This code is picked from galeon-1.3.21.
dnl nsIDocShell::GetSecurityUI was added in 1.8b2 as part of the fastback
dnl patch
dnl https://bugzilla.mozilla.org/show_bug.cgi?id=274784

AC_MSG_CHECKING([whether nsIDocShell::GetSecureUI exists])
AC_COMPILE_IFELSE(
        [AC_LANG_PROGRAM(
                [[#include <nsIDocShell.h>]],
                [[ nsIDocShell *p;
                   p->GetSecurityUI( nsnull ); ]]
        )],
        [AC_DEFINE([HAVE_NSIDOCSHELL_GETSECUREUI], [1],
                   [Define if nsIDocShell::GetSecureUI exists]) result=yes],
        [result=no])
AC_MSG_RESULT([$result])

dnl restore flags
CPPFLAGS=$_SAVE_CPPFLAGS
CXXFLAGS=$_SAVE_CXXFLAGS

AC_LANG_POP([C++])

dnl **************************************************************
dnl Check for Gtk+2.
dnl **************************************************************
dnl Test for GTK+, and define GTK_CFLAGS and GTK_LIBS, if gthread is specified in MODULES, 
dnl pass to pkg-config
AM_PATH_GTK_2_0(2.6.0)
AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
AC_PATH_PROG(GLIB_MKENUMS, glib-mkenums)

dnl **************************************************************
dnl Check for gtk-webcore.
dnl **************************************************************
AC_ARG_ENABLE(gtk_webcore, [  --enable-gtk-webcore
                          Enable GTK-Webcore module for HTML rendering])
if test x"$enable_gtk_webcore" = "xyes"; then
  PKG_CHECK_MODULES(NRCIT, osb-nrcit)
  AC_SUBST(NRCIT_CFLAGS)
  AC_SUBST(NRCIT_LIBS)
  AC_DEFINE(ENABLE_GTK_WEBCORE, 1, [Define using GTK-Webcore support])
fi
AM_CONDITIONAL(ENABLE_GTK_WEBCORE, test x"$enable_gtk_webcore" = "xyes")

dnl **************************************************************
dnl Check for openssl 
dnl **************************************************************
dnl AC_ARG_ENABLE(ssl, [  --disable-ssl
dnl                       Disable OpenSSL suport],,
dnl                       disable_ssl=no)
dnl if test x"$disable_ssl" = "xno"; then
dnl   PKG_CHECK_MODULES(SSL, openssl)
dnl   AC_SUBST(SSL_CFLAGS)
dnl   AC_SUBST(SSL_LIBS)
dnl   AC_DEFINE(USE_SSL, 1, [Define using openssl])
dnl fi
dnl AM_CONDITIONAL(ENABLE_SSL, test x"$disable_ssl" = "xno")

dnl **************************************************************
dnl Check for GNU TLS
dnl **************************************************************
AC_ARG_ENABLE(ssl, [  --disable-ssl
                          Disable GNU TLS suport],,
                          disable_ssl=no)
if test x"$disable_ssl" = "xno"; then
   AM_PATH_LIBGNUTLS(1.2.0,
        AC_DEFINE(USE_SSL, 1, [Define using GNU TLS]),
        AC_MSG_WARN([[libgnutls was not found.]]))
fi
AM_CONDITIONAL(ENABLE_SSL, test x"$disable_ssl" = "xno")

dnl **************************************************************
dnl Check for gettext.
dnl **************************************************************
ALL_LINGUAS="cs fr ja ru"
GETTEXT_PACKAGE=kazehakase
AC_SUBST(GETTEXT_PACKAGE)
AM_GLIB_GNU_GETTEXT
localedir="${datadir}/locale"
AC_SUBST(localedir)

dnl
dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
dnl
dnl kz_save_LIBS=$LIBS
dnl LIBS="$LIBS $GTK_LIBS"
dnl AC_CHECK_FUNCS(bind_textdomain_codeset)
dnl LIBS=$kz_save_LIBS


dnl **************************************************************
dnl Checks for programs.
dnl **************************************************************

AC_ARG_ENABLE(Werror, [  --enable-Werror         Enable -Werror option for GCC])

if test "x$GCC" = "xyes"; then
  case " $CFLAGS " in
  *[\ \ ]-Wall[\ \      ]*) ;;
  *) CFLAGS="$CFLAGS -Wall" ;;
  esac

  case " $CFLAGS " in
  *[\ \ ]-Wmissing-declarations[\ \     ]*) ;;
  *) CFLAGS="$CFLAGS -Wmissing-declarations" ;;
  esac

  case " $CFLAGS " in
  *[\ \ ]-Wmissing-prototypes[\ \       ]*) ;;
  *) CFLAGS="$CFLAGS -Wmissing-prototypes" ;;
  esac

  case " $CFLAGS " in
  *[\ \ ]-Wpointer-arith[\ \    ]*) ;;
  *) CFLAGS="$CFLAGS -Wpointer-arith" ;;
  esac

  case " $CFLAGS " in
  *[\ \ ]-Wcast-align[\ \       ]*) ;;
  *) CFLAGS="$CFLAGS -Wcast-align" ;;
  esac

  if test "x$enable_Werror" = "xyes"; then
    case " $CFLAGS " in
    *[\ \       ]-Werror[\ \    ]*) ;;
    *) CFLAGS="$CFLAGS -Werror" ;;
    esac
  fi

  if test "x$enable_ansi" = "xyes"; then
    case " $CFLAGS " in
    *[\ \       ]-ansi[\ \      ]*) ;;
    *) CFLAGS="$CFLAGS -ansi" ;;
    esac

    case " $CFLAGS " in
    *[\ \       ]-pedantic[\ \  ]*) ;;
    *) CFLAGS="$CFLAGS -pedantic" ;;
    esac
  fi
fi

dnl **************************************************************
dnl Checks for libraries.
dnl **************************************************************
# FIXME: Replace `main' with a function in `-le':
AC_CHECK_LIB([e], [main])
# FIXME: Replace `main' with a function in `-links':
AC_CHECK_LIB([inks], [main])

dnl chekc zlib
AC_CHECK_HEADER(zlib.h,
    [
    dnl zlib.h was found
    HAVE_ZLIB_H="1"
    dnl if the lib wasn't found already, try again with the new paths
    if test "$HAVE_LIBZ" != "1"; then
      AC_CHECK_LIB(z, gzread,
                   [
                   dnl the lib was found!
                   HAVE_LIBZ="1"
                   ],
                   [ CPPFLAGS=$_cppflags
                   LDFLAGS=$_ldflags])
    fi
    ],
    [
      dnl zlib.h was not found, restore the flags
      CPPFLAGS=$_cppflags
      LDFLAGS=$_ldflags]
    )
if test "$HAVE_LIBZ" = "1" && test "$HAVE_ZLIB_H" != "1"
    then
    AC_MSG_WARN([configure found only the libz lib, not the header file!])
elif test "$HAVE_LIBZ" != "1" && test "$HAVE_ZLIB_H" = "1"
    then
    AC_MSG_WARN([configure found only the libz header file, not the lib!])
elif test "$HAVE_LIBZ" = "1" && test "$HAVE_ZLIB_H" = "1"
    then
    ZLIB_LIBS=-lz
    AC_SUBST(ZLIB_LIBS)
fi

dnl **************************************************************
dnl Checks for header files.
dnl **************************************************************
AC_HEADER_STDC
AC_CHECK_HEADERS([fcntl.h libintl.h stdlib.h string.h unistd.h])


dnl **************************************************************
dnl Checks for typedefs, structures, and compiler characteristics.
dnl **************************************************************
AC_C_CONST


dnl **************************************************************
dnl Checks for library functions.
dnl **************************************************************
AC_CHECK_FUNCS([setlocale strchr strtol uname memmove strerror])

dnl **************************************************************
dnl Migemo 
dnl **************************************************************
AC_ARG_ENABLE(migemo, [  --enable-migemo
                          Enable Migemo (Japanese incremental search)])
if test x"$enable_migemo" = "xyes"; then
   AC_DEFINE(USE_MIGEMO, 1, [Define using Migemo support])
fi

dnl **************************************************************
dnl Configure for extentions.
dnl **************************************************************
extdir="${libdir}/\$(PACKAGE)/ext"
AC_SUBST(extdir)

dnl **************************************************************
dnl Extention: Check for Ruby.
dnl **************************************************************
ruby_available="no"
AC_ARG_WITH([ruby],
            AS_HELP_STRING([--with-ruby=PATH],
                           [Ruby interpreter path (default: auto-detect)]),
            [RUBY="$withval"])

if test "$RUBY" = "no"; then
  : # ignore
elif test "$RUBY" = ""; then
  AC_PATH_PROG(RUBY, ruby, none)
  if test "$RUBY" != "none"; then
    ruby_available="yes"
  fi
else
  AC_CHECK_FILE([$RUBY],
                [ruby_available="yes"],
                [AC_MSG_WARN([$RUBY is not found. Disable Ruby extension.])])
fi

if test "$ruby_available" = "yes"; then
  rbconfig="$RUBY -rrbconfig -e "

  changequote(<<, >>)
  for var_name in archdir sitearchdir CFLAGS LIBRUBYARG libdir; do
    rbconfig_tmp=`$rbconfig "print Config::CONFIG['$var_name']"`
    eval "rbconfig_$var_name=\"$rbconfig_tmp\""
  done
  changequote([, ])

  RUBY_CFLAGS="$RUBY_CFLAGS -I$rbconfig_archdir "
  RUBY_CFLAGS="$RUBY_CFLAGS -I$rbconfig_sitearchdir "
  RUBY_CFLAGS="$RUBY_CFLAGS $rbconfig_CFLAGS "
  RUBY_LIBS="$rbconfig_LIBRUBYARG"
  RUBY_LDFLAGS="-L$rbconfig_libdir"

  AC_SUBST(RUBY_CFLAGS)
  AC_SUBST(RUBY_LIBS)
  AC_SUBST(RUBY_LDFLAGS)

  _SAVE_CFLAGS=$CFLAGS
  ruby_undef_package_macros="
#undef PACKAGE_NAME
#undef PACKAGE_TARNAME
#undef PACKAGE_STRING
#undef PACKAGE_VERSION
"
  ruby_disable_message="Disable Ruby extension."
  CFLAGS="$CFLAGS $RUBY_CFLAGS"
  AC_CHECK_HEADERS(ruby.h, [],
                   [ruby_available="no"
                    AC_MSG_WARN([$ruby_disable_message])],
                   [$ruby_undef_package_macros])
  if test "x$ruby_available" = "xyes"; then
    CFLAGS="$CFLAGS $GTK_CFLAGS"
    AC_CHECK_HEADERS(rbgtk.h, [],
                     [ruby_available="no"
                      AC_MSG_WARN([$ruby_disable_message])],
                     [$ruby_undef_package_macros])
  fi
  CFLAGS=$_SAVE_CFLAGS
fi

AM_CONDITIONAL([WITH_RUBY], [test "$ruby_available" = "yes"])


dnl **************************************************************
dnl Configure for gettext from Ruby scripts
dnl **************************************************************
AC_ARG_WITH([rgettext],
            AS_HELP_STRING([--with-rgettext=PATH],
                           [rgettext path (default: auto-detect)]),
            [RGETTEXT="$withval"])

if test "$RGETTEXT" = "no"; then
  RGETTEXT=""
elif test "$RGETTEXT" = ""; then
  AC_PATH_PROG(RGETTEXT, rgettext, none)
  if test "$RGETTEXT" = "none"; then
    RGETTEXT=""
  fi
else
  rgettext_message="$RGETTEXT is not found. Disable gettext from Ruby scripts."
  AC_CHECK_FILE([$RGETTEXT], [],
                [RGETTEXT=""
                 AC_MSG_WARN([$rgettext_message])])
fi

RGETTEXT_TARGETS=""
if test "$RGETTEXT" != ""; then
  changequote(<<, >>)
  for dir in data/ext/ruby; do
    tmp_targets="`find $dir -name '*.rb' -exec echo \$\(top_srcdir\)/\{\} \;`"
    RGETTEXT_TARGETS="$RGETTEXT_TARGETS `echo $tmp_targets | xargs echo`"
  done
  changequote([, ])
fi
AC_SUBST(RGETTEXT_TARGETS)

dnl **************************************************************
dnl Configure for UI XML
dnl **************************************************************
if test "$ruby_available" = "yes" ; then
  UI_XML_RUBY_START=""
  UI_XML_RUBY_END=""
else
  UI_XML_RUBY_START="<!--"
  UI_XML_RUBY_END="-->"
fi

AC_SUBST([UI_XML_RUBY_START])
AC_SUBST([UI_XML_RUBY_END])

KZ_BACKENDS="\$(GECKO)-\$(MOZILLA_COMPONENT_VERSION)"
AC_SUBST([KZ_BACKENDS])

dnl **************************************************************
dnl Configure for history search module.
dnl **************************************************************
searchdir="${libdir}/\$(PACKAGE)/search"
AC_SUBST(searchdir)

dnl **************************************************************
dnl Check for Hyper Estraier.
dnl **************************************************************

est_exists=no
PKG_CHECK_MODULES(EST, hyperestraier,
                  [est_exists=yes], [est_exists=no])
AM_CONDITIONAL([WITH_EST], [test "$est_exists" = "yes"])

dnl **************************************************************
dnl Check for Anthy
dnl **************************************************************

anthy_exists=no
PKG_CHECK_MODULES(ANTHY, anthy,
                  [anthy_exists=yes], [anthy_exists=no])
AM_CONDITIONAL([WITH_ANTHY], [test "$anthy_exists" = "yes"])
MECAB_LIBS=`mecab-config --libs`
MECAB_CFLAGS=`mecab-config --cflags`
AC_SUBST([MECAB_CFLAGS])
AC_SUBST([MECAB_LIBS])
if test x"$anthy_exists" = "xyes"; then
  AC_DEFINE(WITH_ANTHY, 1, [Define including Anthy hugahoge])
fi

AC_SUBST([AM_CPPFLAGS])
AC_SUBST([AM_CFLAGS])
AC_SUBST([AM_CXXFLAGS])
AC_SUBST([AM_LDFLAGS])

AC_CONFIG_FILES([
Makefile
po/Makefile.in
src/Makefile
src/utils/Makefile
src/net/Makefile
src/mozilla/Makefile
src/khtml/Makefile
src/actions/Makefile
src/bookmarks/Makefile
src/dialogs/Makefile
src/prefs_ui/Makefile
src/sidebar/Makefile
src/widget/Makefile
src/libegg/Makefile
src/libegg/md5/Makefile
src/libegg/pixbufthumbnail/Makefile
src/libegg/regex/Makefile
src/libegg/regex/pcre/Makefile
module/Makefile
module/search/Makefile
etc/Makefile
etc/kz-ui-beginner.xml
etc/kz-ui-medium.xml
etc/kz-ui-expert.xml
etc/mozilla/Makefile
ext/Makefile
ext/ruby/Makefile
data/Makefile
data/icons/Makefile
data/ext/Makefile
data/ext/ruby/Makefile
data/ext/ruby/kz/Makefile
data/ext/ruby/kz/actions/Makefile
doc/Makefile
kazehakase.spec
])

AC_OUTPUT