kazehakase/trunk/configure.ac

dnl Process this file with autoconf to produce a configure script.
AC_PREREQ(2.57)

AC_INIT(kazehakase, 0.4.4.1)
AM_INIT_AUTOMAKE(1.6)
AM_CONFIG_HEADER(config.h)

AC_ENABLE_SHARED(yes)
AC_ENABLE_STATIC(no)
AM_PROG_LIBTOOL
 
LT_VERSION_INFO="1:0:1"
LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
AC_SUBST(LT_VERSION_INFO)
AC_SUBST(LIBTOOL_EXPORT_OPTIONS)

AC_PATH_PROG([PKG_CONFIG], [pkg-config], [no])

AC_PROG_CXX
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_AWK

dnl disable RTTI by default
AC_ARG_ENABLE(cpp-rtti,
        [  --enable-cpp-rtti       Enable C++ RTTI (for cvs gcc)],,
        enable_cpp_rtti=no)

if test "x$enable_cpp_rtti" = "xno"; then
  AM_CXXFLAGS="-fno-rtti $AM_CXXFLAGS"
fi

dnl **************************************************************
dnl Configure for embed module.
dnl **************************************************************
embeddir="${libdir}/\$(PACKAGE)/embed"
AC_SUBST(embeddir)

dnl **************************************************************
dnl Check for GtkMozEmbed.
dnl **************************************************************

KAZEHAKASE_GECKO_CHECK

dnl **************************************************************
dnl Check for Gtk+2.
dnl **************************************************************
dnl Test for GTK+, and define GTK_CFLAGS and GTK_LIBS, if gthread is specified in MODULES, 
dnl pass to pkg-config
AM_PATH_GTK_2_0(2.6.0)
AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
AC_PATH_PROG(GLIB_MKENUMS, glib-mkenums)

dnl **************************************************************
dnl Check Glib version
dnl **************************************************************
PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.13.0, GLIB_HAS_NO_REGREX="no", GLIB_HAS_NO_REGEX="yes")
AM_CONDITIONAL(GLIB_HAS_NO_REGEX, test x"$GLIB_HAS_NO_REGEX" = "xyes")

dnl **************************************************************
dnl Check for gtk-webcore.
dnl **************************************************************

gtk_webcore_exists=no
PKG_CHECK_MODULES(NRCIT, osb-nrcit >= 0.5.2,
                  [gtk_webcore_exists=yes], [gtk_webcore_exists=no])
AC_SUBST([NRCIT_CFLAGS])
AC_SUBST([NRCIT_LIBS])
AM_CONDITIONAL([WITH_GTK_WEBCORE], [test x"$gtk_webcore_exists" = "xyes"])

dnl **************************************************************
dnl Check for GNU TLS
dnl **************************************************************
AC_ARG_ENABLE(ssl, [  --disable-ssl
                          Disable GNU TLS suport],,
                          disable_ssl=no)
if test x"$disable_ssl" = "xno"; then
   AM_PATH_LIBGNUTLS(1.2.0,
        AC_DEFINE(USE_SSL, 1, [Define using GNU TLS]),
        AC_MSG_WARN([[libgnutls was not found.]]))
fi
AM_CONDITIONAL(ENABLE_SSL, test x"$disable_ssl" = "xno")

dnl **************************************************************
dnl Check for Session Management
dnl **************************************************************

AC_PATH_XTRA

SM_LIBS=""
sm_save_cppflags="$CPPFLAGS"
CPPFLAGS="$CPPFLAGS $X_CFLAGS"

HAVE_SM=true
AC_CHECK_LIB(SM, SmcSaveYourselfDone,
        [SM_LIBS="$X_LIBS -lSM -lICE"],HAVE_SM=false,
        $X_LIBS -lICE)
AC_CHECK_HEADERS(X11/SM/SMlib.h,,HAVE_SM=false)
if test "$HAVE_SM" = true; then
        AC_DEFINE(HAVE_LIBSM, 1, [Define to 1 if you have libSM installed])
fi

AC_SUBST(SM_LIBS)
CPPFLAGS="$sm_save_cppflags"

dnl **************************************************************
dnl Check for gettext.
dnl **************************************************************
ALL_LINGUAS="cs fr ja ru"
GETTEXT_PACKAGE=kazehakase
AC_SUBST(GETTEXT_PACKAGE)
AM_GLIB_GNU_GETTEXT
localedir="${datadir}/locale"
AC_SUBST(localedir)

dnl **************************************************************
dnl Checks for programs.
dnl **************************************************************

AC_ARG_ENABLE(Werror, [  --enable-Werror         Enable -Werror option for GCC])

if test "x$GCC" = "xyes"; then
  case " $CFLAGS " in
  *[\ \ ]-Wall[\ \      ]*) ;;
  *) CFLAGS="$CFLAGS -Wall" ;;
  esac

  case " $CFLAGS " in
  *[\ \ ]-Wmissing-declarations[\ \     ]*) ;;
  *) CFLAGS="$CFLAGS -Wmissing-declarations" ;;
  esac

  case " $CFLAGS " in
  *[\ \ ]-Wmissing-prototypes[\ \       ]*) ;;
  *) CFLAGS="$CFLAGS -Wmissing-prototypes" ;;
  esac

  case " $CFLAGS " in
  *[\ \ ]-Wpointer-arith[\ \    ]*) ;;
  *) CFLAGS="$CFLAGS -Wpointer-arith" ;;
  esac

  case " $CFLAGS " in
  *[\ \ ]-Wcast-align[\ \       ]*) ;;
  *) CFLAGS="$CFLAGS -Wcast-align" ;;
  esac

  if test "x$enable_Werror" = "xyes"; then
    case " $CFLAGS " in
    *[\ \       ]-Werror[\ \    ]*) ;;
    *) CFLAGS="$CFLAGS -Werror" ;;
    esac
  fi

  if test "x$enable_ansi" = "xyes"; then
    case " $CFLAGS " in
    *[\ \       ]-ansi[\ \      ]*) ;;
    *) CFLAGS="$CFLAGS -ansi" ;;
    esac

    case " $CFLAGS " in
    *[\ \       ]-pedantic[\ \  ]*) ;;
    *) CFLAGS="$CFLAGS -pedantic" ;;
    esac
  fi
fi

dnl **************************************************************
dnl Checks for libraries.
dnl **************************************************************
# FIXME: Replace `main' with a function in `-le':
AC_CHECK_LIB([e], [main])
# FIXME: Replace `main' with a function in `-links':
AC_CHECK_LIB([inks], [main])


AC_CHECK_HEADER(winsock2.h,
[AC_CACHE_CHECK([for socket in -lwsock32], [ac_kz_lib_wsock32],
   [LIBS_save=$LIBS
    LIBS="-lwsock32 $LIBS"
    AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <winsock2.h>
                                    ],
                                    [socket(0,0,0)])],
                   [AS_VAR_SET([ac_kz_lib_wsock32], [yes])
                    SOCKET_LIBS="-lwsock32 $SOCKET_LIBS"],
                   [AS_VAR_SET([ac_kz_lib_wsock32], [no])])
    LIBS=$LIBS_save])

 AC_CACHE_CHECK([for WSASocket in -lws2_32], [ac_kz_lib_ws2_32],
   [LIBS_save=$LIBS
    LIBS="-lws2_32 $LIBS"
    AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <winsock2.h>
                                    ],
                                    [WSASocket(0,0,0,0,0,0)])],
                   [AS_VAR_SET([ac_kz_lib_ws2_32], [yes])
                    SOCKET_LIBS="-lws2_32 $SOCKET_LIBS"],
                   [AS_VAR_SET([ac_kz_lib_ws2_32], [no])])
    LIBS=$LIBS_save])])
AC_SUBST(SOCKET_LIBS)

dnl chekc zlib
AC_CHECK_HEADER(zlib.h,
    [
    dnl zlib.h was found
    HAVE_ZLIB_H="1"
    dnl if the lib wasn't found already, try again with the new paths
    if test "$HAVE_LIBZ" != "1"; then
      AC_CHECK_LIB(z, gzread,
                   [
                   dnl the lib was found!
                   HAVE_LIBZ="1"
                   ],
                   [ CPPFLAGS=$_cppflags
                   LDFLAGS=$_ldflags])
    fi
    ],
    [
      dnl zlib.h was not found, restore the flags
      CPPFLAGS=$_cppflags
      LDFLAGS=$_ldflags]
    )
if test "$HAVE_LIBZ" = "1" && test "$HAVE_ZLIB_H" != "1"
    then
    AC_MSG_WARN([configure found only the libz lib, not the header file!])
elif test "$HAVE_LIBZ" != "1" && test "$HAVE_ZLIB_H" = "1"
    then
    AC_MSG_WARN([configure found only the libz header file, not the lib!])
elif test "$HAVE_LIBZ" = "1" && test "$HAVE_ZLIB_H" = "1"
    then
    ZLIB_LIBS=-lz
    AC_SUBST(ZLIB_LIBS)
fi

dnl **************************************************************
dnl Checks for header files.
dnl **************************************************************
AC_HEADER_STDC
AC_CHECK_HEADERS([fcntl.h libintl.h stdlib.h string.h unistd.h])


dnl **************************************************************
dnl Checks for typedefs, structures, and compiler characteristics.
dnl **************************************************************
AC_C_CONST


dnl **************************************************************
dnl Checks for library functions.
dnl **************************************************************
AC_CHECK_FUNCS([setlocale strchr strtol uname memmove strerror])
AC_CHECK_FUNC([strptime], [have_strptime=yes], [have_strptime=no])
AM_CONDITIONAL(HAVE_STRPTIME, test x"$have_strptime" = "xyes")

dnl **************************************************************
dnl Migemo 
dnl **************************************************************
AC_ARG_ENABLE(migemo, [  --enable-migemo
                          Enable Migemo (Japanese incremental search)])
if test x"$enable_migemo" = "xyes"; then
   AC_DEFINE(USE_MIGEMO, 1, [Define using Migemo support])
fi

dnl **************************************************************
dnl Configure for extentions.
dnl **************************************************************
extdir="${libdir}/\$(PACKAGE)/ext"
AC_SUBST(extdir)

dnl **************************************************************
dnl Extention: Check for Ruby.
dnl **************************************************************
ruby_available="no"
AC_ARG_WITH([ruby],
            AS_HELP_STRING([--with-ruby=PATH],
                           [Ruby interpreter path (default: auto-detect)]),
            [RUBY="$withval"])

if test "$RUBY" = "no"; then
  : # ignore
elif test "$RUBY" = ""; then
  AC_PATH_PROG(RUBY, ruby, none)
  if test "$RUBY" != "none"; then
    ruby_available="yes"
  fi
else
  AC_CHECK_FILE([$RUBY],
                [ruby_available="yes"],
                [AC_MSG_WARN([$RUBY is not found. Disable Ruby extension.])])
fi

if test "$ruby_available" = "yes"; then
  rbconfig="$RUBY -rrbconfig -e "

  changequote(<<, >>)
  for var_name in archdir sitearchdir CFLAGS LIBRUBYARG libdir; do
    rbconfig_tmp=`$rbconfig "print Config::CONFIG['$var_name']"`
    eval "rbconfig_$var_name=\"$rbconfig_tmp\""
  done
  changequote([, ])

  RUBY_CFLAGS="$RUBY_CFLAGS -I$rbconfig_archdir "
  RUBY_CFLAGS="$RUBY_CFLAGS -I$rbconfig_sitearchdir "
  RUBY_CFLAGS="$RUBY_CFLAGS $rbconfig_CFLAGS "
  RUBY_LIBS="$rbconfig_LIBRUBYARG"
  RUBY_LDFLAGS="-L$rbconfig_libdir"

  AC_SUBST(RUBY_CFLAGS)
  AC_SUBST(RUBY_LIBS)
  AC_SUBST(RUBY_LDFLAGS)

  _SAVE_CFLAGS=$CFLAGS
  ruby_undef_package_macros="
#undef PACKAGE_NAME
#undef PACKAGE_TARNAME
#undef PACKAGE_STRING
#undef PACKAGE_VERSION
"
  ruby_disable_message="Disable Ruby extension."
  CFLAGS="$CFLAGS $RUBY_CFLAGS"
  AC_CHECK_HEADERS(ruby.h, [],
                   [ruby_available="no"
                    AC_MSG_WARN([$ruby_disable_message])],
                   [$ruby_undef_package_macros])
  if test "x$ruby_available" = "xyes"; then
    CFLAGS="$CFLAGS $GTK_CFLAGS"
    AC_CHECK_HEADERS(rbgtk.h, [],
                     [ruby_available="no"
                      AC_MSG_WARN([$ruby_disable_message])],
                     [$ruby_undef_package_macros])
  fi
  CFLAGS=$_SAVE_CFLAGS
fi

AM_CONDITIONAL([WITH_RUBY], [test "$ruby_available" = "yes"])


dnl **************************************************************
dnl Configure for gettext from Ruby scripts
dnl **************************************************************
AC_ARG_WITH([rgettext],
            AS_HELP_STRING([--with-rgettext=PATH],
                           [rgettext path (default: auto-detect)]),
            [RGETTEXT="$withval"])

if test "$RGETTEXT" = "no"; then
  RGETTEXT=""
elif test "$RGETTEXT" = ""; then
  AC_PATH_PROG(RGETTEXT, rgettext, none)
  if test "$RGETTEXT" = "none"; then
    RGETTEXT=""
  fi
else
  rgettext_message="$RGETTEXT is not found. Disable gettext from Ruby scripts."
  AC_CHECK_FILE([$RGETTEXT], [],
                [RGETTEXT=""
                 AC_MSG_WARN([$rgettext_message])])
fi

RGETTEXT_TARGETS=""
if test "$RGETTEXT" != ""; then
  changequote(<<, >>)
  for dir in data/ext/ruby; do
    tmp_targets="`find $dir -name '*.rb' -exec echo \$\(top_srcdir\)/\{\} \;`"
    RGETTEXT_TARGETS="$RGETTEXT_TARGETS `echo $tmp_targets | xargs echo`"
  done
  changequote([, ])
fi
AC_SUBST(RGETTEXT_TARGETS)

dnl **************************************************************
dnl Configure for UI XML
dnl **************************************************************
if test "$ruby_available" = "yes" ; then
  UI_XML_RUBY_START=""
  UI_XML_RUBY_END=""
else
  UI_XML_RUBY_START="<!--"
  UI_XML_RUBY_END="-->"
fi

AC_SUBST([UI_XML_RUBY_START])
AC_SUBST([UI_XML_RUBY_END])

KZ_BACKENDS="\$(GECKO)-\$(MOZILLA_COMPONENT_VERSION)"
AC_SUBST([KZ_BACKENDS])

dnl **************************************************************
dnl Configure for history search module.
dnl **************************************************************
searchdir="${libdir}/\$(PACKAGE)/search"
AC_SUBST(searchdir)

dnl **************************************************************
dnl Check for Hyper Estraier.
dnl **************************************************************

est_exists=no
AC_ARG_ENABLE([heyper-estraier],
              AS_HELP_STRING([--disable-hyper-estraier],
                             [Disable Hyper Estraier support]))
if test "x$enable_hyper_estraier" = "x" -o \
        "x$enable_hyper_estraier" = "xyes"; then
  PKG_CHECK_MODULES(EST, hyperestraier,
                    [est_exists=yes], [est_exists=no])
fi
AM_CONDITIONAL([WITH_EST], [test "$est_exists" = "yes"])

dnl **************************************************************
dnl Check for Anthy
dnl **************************************************************

anthy_exists=no
PKG_CHECK_MODULES(ANTHY, anthy,
                  [anthy_exists=yes], [anthy_exists=no])

AC_PATH_PROG(MECAB_CONFIG, mecab-config, "none")
if test x"$MECAB_CONFIG" = x"none"; then
  mecab_exists=no
  MECAB_LIBS=""
  MECAB_CFLAGS=""
else
  mecab_exists=yes
  MECAB_LIBS=`$MECAB_CONFIG --libs`
  MECAB_CFLAGS=`$MECAB_CONFIG --cflags`
fi
AC_SUBST([MECAB_CFLAGS])
AC_SUBST([MECAB_LIBS])

if test x"$anthy_exists" = "xyes" -a x"$mecab_exists" = "xyes" ; then
  anthy_trainer_available="yes"
else
  anthy_trainer_available="no"
fi

anthy_trainer_available="no"
AM_CONDITIONAL([WITH_ANTHY_TRAINER], [test x"$anthy_trainer_available" = "xyes"])
if test x"$anthy_trainer_available" = "xyes" ; then
  AC_DEFINE(WITH_ANTHY_TRAINER, 1, [Define to 1 if Anthy and Mecab is found])
fi

dnl **************************************************************
dnl Check for MinGW
dnl **************************************************************

AC_ARG_ENABLE([mingw-debug],
              AS_HELP_STRING([--enable-mingw-debug],
                             [Enable MinGW debug]))
case $host_os in
mingw*)
  if test "x$enable_mingw_debug" != "xno"; then
    LDFLAGS="$LDFLAGS -mwindows"
  fi
  AC_CHECK_TOOL(WINDRES, windres)
  ;;
esac
AM_CONDITIONAL([HAVE_WINDRES], [test x"$WINDRES" != x])

AC_SUBST([AM_CPPFLAGS])
AC_SUBST([AM_CFLAGS])
AC_SUBST([AM_CXXFLAGS])
AC_SUBST([AM_LDFLAGS])

AC_CONFIG_FILES([
Makefile
po/Makefile.in
src/Makefile
src/missing/Makefile
src/utils/Makefile
src/utils/pcre/Makefile
src/net/Makefile
src/actions/Makefile
src/bookmarks/Makefile
src/dialogs/Makefile
src/prefs_ui/Makefile
src/sidebar/Makefile
src/widget/Makefile
src/libegg/Makefile
src/libegg/md5/Makefile
src/libegg/pixbufthumbnail/Makefile
module/Makefile
module/embed/Makefile
module/embed/gecko/Makefile
module/embed/gtk-webcore/Makefile
module/search/Makefile
etc/Makefile
etc/kz-ui-beginner.xml
etc/kz-ui-medium.xml
etc/kz-ui-expert.xml
etc/mozilla/Makefile
ext/Makefile
ext/ruby/Makefile
data/Makefile
data/icons/Makefile
data/ext/Makefile
data/ext/ruby/Makefile
data/ext/ruby/kz/Makefile
data/ext/ruby/kz/actions/Makefile
doc/Makefile
kazehakase.spec
])

AC_OUTPUT